326 lines
9.4 KiB
VimL
326 lines
9.4 KiB
VimL
" Sane vim defaults for ArchLabs
|
|
|
|
" Arch defaults
|
|
runtime! archlinux.vim
|
|
|
|
" additional settings
|
|
set modeline " enable vim modelines
|
|
set hlsearch " highlight search items
|
|
set incsearch " searches are performed as you type
|
|
set clipboard^=unnamedplus " system clipboard (requires +clipboard)
|
|
set number " enable line numbers
|
|
set confirm " ask confirmation for some things, like save before quit, etc.
|
|
set wildmenu " Tab completion menu when using command mode
|
|
set expandtab " Tab key inserts spaces not tabs
|
|
set softtabstop=4 " spaces to enter for each tab
|
|
set shiftwidth=4 " amount of spaces for indentation
|
|
set shortmess+=aAcIws " Hide or shorten certain messages
|
|
|
|
let g:netrw_altv = 1
|
|
let g:netrw_liststyle = 3
|
|
let g:netrw_browse_split = 3
|
|
|
|
" ------ leader mapping ------
|
|
|
|
let g:mapleader = ','
|
|
map <Space> ,
|
|
|
|
" ------ enable additional features ------
|
|
|
|
" enable mouse
|
|
set mouse=a
|
|
if has('mouse_sgr')
|
|
" sgr mouse is better but not every term supports it
|
|
set ttymouse=sgr
|
|
endif
|
|
|
|
" syntax highlighting
|
|
syntax enable
|
|
|
|
if has('termguicolors') && $DISPLAY !=? '' && &t_Co == 256
|
|
set termguicolors " true colors in the terminal
|
|
try
|
|
let g:jinx_colors = 'night' " night or day, 'T' to change on the fly
|
|
colorscheme jinx
|
|
catch
|
|
colorscheme evening
|
|
endtry
|
|
|
|
" fix true colors in some terminals (neovim doesn't seem to have this issue)
|
|
if !has('nvim') && !($TERM =~? 'xterm' || &term =~? 'xterm')
|
|
let $TERM = 'xterm-256color'
|
|
let &term = 'xterm-256color'
|
|
endif
|
|
else
|
|
try
|
|
colorscheme jinx
|
|
catch
|
|
colorscheme evening
|
|
endtry
|
|
endif
|
|
|
|
" change cursor shape for different editing modes, neovim does this by default
|
|
if !has('nvim')
|
|
if exists('$TMUX')
|
|
let &t_SI = "\<Esc>Ptmux;\<Esc>\e[5 q\<Esc>\\"
|
|
let &t_SR = "\<Esc>Ptmux;\<Esc>\e[4 q\<Esc>\\"
|
|
let &t_EI = "\<Esc>Ptmux;\<Esc>\e[2 q\<Esc>\\"
|
|
else
|
|
let &t_SI = "\e[6 q"
|
|
let &t_SR = "\e[4 q"
|
|
let &t_EI = "\e[2 q"
|
|
endif
|
|
endif
|
|
|
|
set linebreak " wrap lines at full words rather than the last character to fit
|
|
set breakindent " wrapped lines match the same indent level
|
|
|
|
set list listchars=tab:>>,trail:~
|
|
if has('multi_byte') && $DISPLAY !=? ''
|
|
set listchars=tab:»»,trail:•
|
|
set fillchars=vert:┃ showbreak=↪
|
|
endif
|
|
|
|
" ------ commands ------
|
|
|
|
command! D Explore
|
|
command! R call <SID>ranger()
|
|
command! Q call <SID>quitbuffer()
|
|
command! -nargs=1 B :call <SID>bufferselect("<args>")
|
|
command! W execute 'silent w !sudo tee % >/dev/null' | edit!
|
|
|
|
" ------ basic maps ------
|
|
|
|
" open ranger as a file chooser using the function below
|
|
nnoremap <leader>r :call <SID>ranger()<CR>
|
|
|
|
" match string to switch buffer
|
|
nnoremap <Leader>b :let b:buf = input('Match: ')<Bar>call <SID>bufferselect(b:buf)<CR>
|
|
|
|
" paste while in insert mode
|
|
inoremap <silent><C-v> <Esc>:set paste<CR>a<C-r>+<Esc>:set nopaste<CR>a
|
|
|
|
" change windows with ctrl+(hjkl)
|
|
nnoremap <C-J> <C-W><C-J>
|
|
nnoremap <C-K> <C-W><C-K>
|
|
nnoremap <C-L> <C-W><C-L>
|
|
nnoremap <C-H> <C-W><C-H>
|
|
|
|
" alt defaults
|
|
nnoremap 0 ^
|
|
nnoremap Y y$
|
|
nnoremap n nzzzv
|
|
nnoremap N Nzzzv
|
|
nnoremap <Tab> ==j
|
|
|
|
" re-visual text after changing indent
|
|
vnoremap > >gv
|
|
vnoremap < <gv
|
|
|
|
" j = gj :: k = gk while preserving numbered jumps eg. 12j
|
|
nnoremap <buffer><silent><expr>j v:count ? 'j' : 'gj'
|
|
nnoremap <buffer><silent><expr>k v:count ? 'k' : 'gk'
|
|
|
|
" open a terminal in $PWD
|
|
nnoremap <silent> <Leader>tt :terminal<CR>
|
|
|
|
" tab control
|
|
nnoremap <silent> <M-j> :tabmove -1<CR>
|
|
nnoremap <silent> <M-k> :tabmove +1<CR>
|
|
nnoremap <silent> <Leader>te :tabnew<CR>
|
|
nnoremap <silent> <Leader>tn :tabnext<CR>
|
|
nnoremap <silent> <Leader>tf :tabfirst<CR>
|
|
nnoremap <silent> <Leader>tp :tabprevious<CR>
|
|
|
|
" close current buffer and/or tab
|
|
nnoremap <silent> <Leader>q :B<CR>:silent tabclose<CR>gT
|
|
nnoremap <silent> <Leader>tl :execute "tabn ".g:lasttab<CR>
|
|
|
|
" open a new tab in the current directory with netrw
|
|
nnoremap <silent> <Leader>- :tabedit <C-R>=expand("%:p:h")<CR><CR>
|
|
|
|
" split the window vertically and horizontally
|
|
nnoremap _ <C-W>s<C-W><Down>
|
|
nnoremap <Bar> <C-W>v<C-W><Right>
|
|
|
|
|
|
" ------ autocmd ------
|
|
|
|
let g:lasttab = 1
|
|
augroup save_last_tab
|
|
autocmd!
|
|
autocmd TabLeave * let g:lasttab = tabpagenr()
|
|
augroup END
|
|
|
|
" Reload changes if file changed outside of vim requires autoread
|
|
augroup load_changed_file
|
|
autocmd!
|
|
autocmd FocusGained,BufEnter * if mode() !=? 'c' | checktime | endif
|
|
autocmd FileChangedShellPost * echo "Changes loaded from source file"
|
|
augroup END
|
|
|
|
" when quitting a file, save the cursor position
|
|
augroup save_cursor_position
|
|
autocmd!
|
|
autocmd BufReadPost * call setpos(".", getpos("'\""))
|
|
augroup END
|
|
|
|
" when not running in a console or a terminal that doesn't support 256 colors
|
|
" enable cursorline in the currently active window and disable it in inactive ones
|
|
if $DISPLAY !=? '' && &t_Co == 256
|
|
augroup cursorline
|
|
autocmd!
|
|
autocmd VimEnter,WinEnter,BufWinEnter * setlocal cursorline
|
|
autocmd WinLeave * setlocal nocursorline
|
|
augroup END
|
|
endif
|
|
|
|
" ------ adv maps ------
|
|
|
|
" toggle line numbers, nn (no number)
|
|
nnoremap <silent> <Leader>nn
|
|
\ :if &number <Bar>
|
|
\ set nonumber
|
|
\ <Bar> echo 'Line numbers disabled'
|
|
\ <Bar> else <Bar>
|
|
\ set number
|
|
\ <Bar> echo 'Line numbers enabled'
|
|
\ <Bar> endif<CR>
|
|
|
|
" strip trailing whitespace, ss (strip space)
|
|
nnoremap <silent> <Leader>ss
|
|
\ :let b:_p = getpos(".") <Bar>
|
|
\ let b:_s = (@/ != '') ? @/ : '' <Bar>
|
|
\ %s/\s\+$//e <Bar>
|
|
\ let @/ = b:_s <Bar>
|
|
\ nohlsearch <Bar>
|
|
\ unlet b:_s <Bar>
|
|
\ call setpos('.', b:_p) <Bar>
|
|
\ unlet b:_p <CR>
|
|
|
|
" global replace
|
|
vnoremap <Leader>sw "hy
|
|
\ :let b:sub = input('global replacement: ') <Bar>
|
|
\ if b:sub !=? '' <Bar>
|
|
\ let b:rep = substitute(getreg('h'), '/', '\\/', 'g') <Bar>
|
|
\ execute '%s/'.b:rep."/".b:sub.'/g' <Bar>
|
|
\ unlet b:sub b:rep <Bar>
|
|
\ endif <CR>
|
|
nnoremap <Leader>sw
|
|
\ :let b:sub = input('global replacement: ') <Bar>
|
|
\ if b:sub !=? '' <Bar>
|
|
\ execute "%s/<C-r><C-w>/".b:sub.'/g' <Bar>
|
|
\ unlet b:sub <Bar>
|
|
\ endif <CR>
|
|
|
|
" prompt before each replace
|
|
vnoremap <Leader>cw "hy
|
|
\ :let b:sub = input('interactive replacement: ') <Bar>
|
|
\ if b:sub !=? '' <Bar>
|
|
\ let b:rep = substitute(getreg('h'), '/', '\\/', 'g') <Bar>
|
|
\ execute '%s/'.b:rep.'/'.b:sub.'/gc' <Bar>
|
|
\ unlet b:sub b:rep <Bar>
|
|
\ endif <CR>
|
|
nnoremap <Leader>cw
|
|
\ :let b:sub = input('interactive replacement: ') <Bar>
|
|
\ if b:sub !=? '' <Bar>
|
|
\ execute "%s/<C-r><C-w>/".b:sub.'/gc' <Bar>
|
|
\ unlet b:sub <Bar>
|
|
\ endif <CR>
|
|
|
|
" highlight long lines, ll (long lines)
|
|
let w:longlines = matchadd('ColorColumn', '\%'.&textwidth.'v', &textwidth)
|
|
nnoremap <silent> <Leader>ll
|
|
\ :if exists('w:longlines') <Bar>
|
|
\ silent! call matchdelete(w:longlines) <Bar>
|
|
\ echo 'Long line highlighting disabled'
|
|
\ <Bar> unlet w:longlines <Bar>
|
|
\ elseif &textwidth > 0 <Bar>
|
|
\ let w:longlines = matchadd('ColorColumn', '\%'.&textwidth.'v', &textwidth) <Bar>
|
|
\ echo 'Long line highlighting enabled'
|
|
\ <Bar> else <Bar>
|
|
\ let w:longlines = matchadd('ColorColumn', '\%80v', 81) <Bar>
|
|
\ echo 'Long line highlighting enabled'
|
|
\ <Bar> endif <CR>
|
|
|
|
" local keyword jump
|
|
nnoremap <Leader>fw
|
|
\ [I:let b:jump = input('Go To: ') <Bar>
|
|
\ if b:jump !=? '' <Bar>
|
|
\ execute "normal! ".b:jump."[\t" <Bar>
|
|
\ unlet b:jump <Bar>
|
|
\ endif <CR>
|
|
|
|
|
|
" quit the current buffer and switch to the next
|
|
" without this vim will leave you on an empty buffer after quiting the current
|
|
function! <SID>quitbuffer() abort
|
|
let l:bf = bufnr('%')
|
|
let l:pb = bufnr('#')
|
|
if buflisted(l:pb)
|
|
buffer #
|
|
else
|
|
bnext
|
|
endif
|
|
if bufnr('%') == l:bf
|
|
new
|
|
endif
|
|
if buflisted(l:bf)
|
|
execute('bdelete! ' . l:bf)
|
|
endif
|
|
endfunction
|
|
|
|
" switch active buffer based on pattern matching
|
|
" if more than one match is found then list the matches to choose from
|
|
function! <SID>bufferselect(pattern) abort
|
|
let l:bufcount = bufnr('$')
|
|
let l:currbufnr = 1
|
|
let l:nummatches = 0
|
|
let l:matchingbufnr = 0
|
|
" walk the buffer count
|
|
while l:currbufnr <= l:bufcount
|
|
if (bufexists(l:currbufnr))
|
|
let l:currbufname = bufname(l:currbufnr)
|
|
if (match(l:currbufname, a:pattern) > -1)
|
|
echo l:currbufnr.': '.bufname(l:currbufnr)
|
|
let l:nummatches += 1
|
|
let l:matchingbufnr = l:currbufnr
|
|
endif
|
|
endif
|
|
let l:currbufnr += 1
|
|
endwhile
|
|
|
|
" only one match
|
|
if (l:nummatches == 1)
|
|
execute ':buffer '.l:matchingbufnr
|
|
elseif (l:nummatches > 1)
|
|
" more than one match
|
|
let l:desiredbufnr = input('Enter buffer number: ')
|
|
if (strlen(l:desiredbufnr) != 0)
|
|
execute ':buffer '.l:desiredbufnr
|
|
endif
|
|
else
|
|
echoerr 'No matching buffers'
|
|
endif
|
|
endfunction
|
|
|
|
" open ranger as a file chooser
|
|
function! <SID>ranger()
|
|
let l:temp = tempname()
|
|
execute 'silent !xterm -e ranger --choosefiles='.shellescape(l:temp).' $PWD'
|
|
if !filereadable(temp)
|
|
redraw!
|
|
return
|
|
endif
|
|
let l:names = readfile(l:temp)
|
|
if empty(l:names)
|
|
redraw!
|
|
return
|
|
endif
|
|
execute 'edit '.fnameescape(l:names[0])
|
|
for l:name in l:names[1:]
|
|
execute 'argadd '.fnameescape(l:name)
|
|
endfor
|
|
redraw!
|
|
endfunction
|